Шаблоны кода 1С


Добавить новый Назад

Отправка электронной почты

Отправка электронной почты

Почта

Профиль = Новый ИнтернетПочтовыйПрофиль;
   Профиль.АдресСервераSMTP = "";
   Профиль.ПользовательSMTP = "";
   Профиль.ПарольSMTP = "";
   Профиль.ИспользоватьSSLSMTP = false;
   Профиль.ПортSMTP = 25; 
   Профиль.АутентификацияSMTP = СпособSMTPАутентификации.БезАутентификации;

   Письмо = Новый ИнтернетПочтовоеСообщение;
   Текст1 = Письмо.Тексты.Добавить(Текст);
   Текст1.ТипТекста = ТипТекстаПочтовогоСообщения.ПростойТекст;
   Письмо.Тема = Тема; 
   Письмо.Отправитель = "";
   Письмо.ИмяОтправителя = "Сообщение от 1с";
   Письмо.Получатели.Добавить("");
   
   Почта = Новый ИнтернетПочта;     
   Попытка
      Почта.Подключиться(Профиль);
      Сообщить("Подключено");
   Исключение
       Сообщить("Не удалось подключиться к серверу");
       Сообщить(ОписаниеОшибки());
   КонецПопытки;
   Попытка
      Почта.Послать(Письмо);
      Сообщить("Письмо отправлено");
   Исключение
       Сообщить("Не удалось отправить письмо");
       Сообщить(ОписаниеОшибки());
   КонецПопытки;
    
   Почта.Отключиться();
   Сообщить("Соединение завершено");
Добавить комментарий

Удаление строк таблицы по условию

Обратный цикл по таблице значений с удалением строк по условию

Для Индекс = -ТЗ.Количество()+1 По -1 Цикл
	Стр =ТЗ.Получить(-Индекс);
	Если Найти(Стр.Имя, "ПодстрокаПоиска") > 0 Тогда
		ТЗ.Удалить(Стр);
	КонецЕсли;
КонецЦикла;
Комментарии: 3

Произношение текста голосом

произносит заданную фразу

Сообщить Голос Звук Диалог

Voice = Новый COMObject("SAPI.SpVoice");
Voice.Speak("Привет!");
Добавить комментарий

Задать вопрос

Вопрос и обработка ответа без синхронных методов (не модально)

Вопрос Оповещение Диалог Немодально

&НаКлиенте
Процедура ДиалогСВопросом(Команда)
     Оповещение = Новый ОписаниеОповещения("ПослеЗакрытияВопроса", ЭтотОбъект);	
     ПоказатьВопрос(Оповещение,  "Текст вопроса",  
        РежимДиалогаВопрос.ДаНетОтмена,
        0, // таймаут в секундах
        КодВозвратаДиалога.Да, // кнопка по умолчанию
        "Заголовок" 
    );    
КонецПроцедуры
 
&НаКлиенте
Процедура ПослеЗакрытияВопроса(Результат, Параметры) Экспорт
     Если Результат = КодВозвратаДиалога.Да Тогда
        Сообщить("Ответ Да!");
    КонецЕсли;	
 КонецПроцедуры
Добавить комментарий

Пауза, ожидание в коде

Пауза выполнения кода

Пауза ожидание таймер

Процедура Ожидание(МСекунды)
	Перем Таймер;
	Таймер     = ТекущаяУниверсальнаяДатаВМиллисекундах() + МСекунды;
	Пока Таймер > ТекущаяУниверсальнаяДатаВМиллисекундах() Цикл
		Состояние(ОКР((Таймер-ТекущаяУниверсальнаяДатаВМиллисекундах())/1000),1);
	КонецЦикла;
КонецПроцедуры
Комментарии: 1

Преобразование ЧтениеJSON в Соответствие

Преобразует ЧтениеJSON любой глубины в Соответствие. Пример вызова: //JSONТекст - исходный текст в формате JSON Результат = Неопределено; ЧтениеJSON = Новый ЧтениеJSON; ЧтениеJSON.УстановитьСтроку(JSONТекст); ОбработатьJSON(ЧтениеJSON, Результат); //Здесь на выходе из процедуры Результат = Соответствие;

ЧтениеJSON JSON Соответствие.

&НаСервере
Процедура ОбработатьJSON(ЧтениеJSON, Результат)
	
	ИмяСвойства = Неопределено;
	
	Пока ЧтениеJSON.Прочитать() Цикл
		TипJSON = ЧтениеJSON.ТипТекущегоЗначения;
		
		Если TипJSON = ТипЗначенияJSON.НачалоОбъекта 
			ИЛИ TипJSON = ТипЗначенияJSON.НачалоМассива Тогда
			НовыйОбъект = ?(TипJSON = ТипЗначенияJSON.НачалоОбъекта, Новый Соответствие, Новый Массив);
			
			Если ТипЗнч(Результат) = Тип("Массив") Тогда
				Результат.Добавить(НовыйОбъект);
			ИначеЕсли ТипЗнч(Результат) = Тип("Соответствие") И ЗначениеЗаполнено(ИмяСвойства) Тогда
				Результат.Вставить(ИмяСвойства, НовыйОбъект);
			КонецЕсли;
			
			ОбработатьJSON(ЧтениеJSON, НовыйОбъект);
			
			Если Результат = Неопределено Тогда
				Результат = НовыйОбъект;
			КонецЕсли;
		ИначеЕсли TипJSON = ТипЗначенияJSON.ИмяСвойства Тогда
			ИмяСвойства = ЧтениеJSON.ТекущееЗначение;
		ИначеЕсли TипJSON = ТипЗначенияJSON.Число 
			ИЛИ TипJSON = ТипЗначенияJSON.Строка 
			ИЛИ TипJSON = ТипЗначенияJSON.Булево 
			ИЛИ TипJSON = ТипЗначенияJSON.Null Тогда
			Если ТипЗнч(Результат) = Тип("Массив") Тогда
				Результат.Добавить(ЧтениеJSON.ТекущееЗначение);
			ИначеЕсли ТипЗнч(Результат) = Тип("Соответствие") Тогда
				Результат.Вставить(ИмяСвойства, ЧтениеJSON.ТекущееЗначение);
			КонецЕсли;
		Иначе
			Возврат;
		КонецЕсли;
	КонецЦикла;
	
КонецПроцедуры
Добавить комментарий

Последняя строка таблицы на одной странице вместе с подвалом

ВместеСоСледующим

Добавил: Dmitry Zhurbenko
 //После цикла вывода строк

ТабДок.Область(ТабДок.ВысотаТаблицы, ,ТабДок.ВысотаТаблицы,).ВместеСоСледующим = Истина;
Комментарии: 1

Отладка внешних печатных форм

Отладка внешних печатных форм

печатная форма отладка

Адрес = "C:\Эля\кИТ_ВнешняяРеализацияТоваровУслуг.epf";
Обр = ВнешниеОбработки.Создать(Адрес, БезопасныйРежим());
Обр.Печать(МассивОбъектов, КоллекцияПечатныхФорм, ОбъектыПечати, ПараметрыВывода);
Возврат;
Добавить комментарий

Чтение файлов Exсel в таблицу значений (автоматическое наименование столбцов)

Функция считывает содержимое страницы файла Exсel в таблицу значений, автоматически именует столбцы таблицы по первой строке файла. Пробелы заменяются на "".

Таблица значений чтение Excel Excel

&НаСервере
Функция ПодготовитьТаблицуСДанными(ФайлАдресВХранилище)
	
	ИмяФайлаСервер = ПолучитьИмяВременногоФайла(".xlsx");
	ФайлИмпорта = ПолучитьИзВременногоХранилища(ФайлАдресВХранилище);
	ФайлИмпорта.Записать(ИмяФайлаСервер);
	
	ТабличныйДокумент = Новый ТабличныйДокумент;
	Попытка
		ТабличныйДокумент.Прочитать(ИмяФайлаСервер, СпособЧтенияЗначенийТабличногоДокумента.Текст);
	Исключение
		Сообщение = Новый СообщениеПользователю;
		Сообщение.Текст = ОписаниеОшибки();
		Сообщение.Сообщить();
	КонецПопытки;	
	
	ПЗ = Новый ПостроительЗапроса;
	ПЗ.ИсточникДанных = Новый ОписаниеИсточникаДанных(ТабличныйДокумент.Область());
	ПЗ.ДобавлениеПредставлений = ТипДобавленияПредставлений.НеДобавлять;
	ПЗ.ЗаполнитьНастройки();
	ПЗ.Выполнить();
	
	ТаблицаПромежуточныхДанных = ПЗ.Результат.Выгрузить();
	
	Возврат	ТаблицаПромежуточныхДанных;
	
КонецФункции
Комментарии: 1

Отбор по таблице значений

Отбор строк по таблице значений

отбор ТаблицаЗначений ТЗ таблица значений

СтруктураОтбора = Новый Структура("Номенклатура,ХарактеристикаНоменклатуры", ЗначениеОтбора.Номенклатура, ЗначениеОтбора.ХарактеристикаНоменклатуры);
РезультатОтбора = ТаблицаЗначений.НайтиСтроки(СтруктураОтбора);
//Если РезультатОтбора.Количество() > 0 Тогда
//	СтрокаОтбора = РезультатОтбора[0];
//КонецЕсли;
Для каждого СтрокаОтбора Из РезультатОтбора Цикл
	
КонецЦикла;
Добавить комментарий

TurboConf

Удобный поиск шаблонов кода

прямо в Конфигураторе

Узнать подробнее