Добавлен блок Alt+A

Изменен блок Alt+C

Удален блок Alt+D

Либо можно вызвать функцию ТурбоКнопкой

Шаблоны полностью настраиваются. Настройки скрипта хранятся в папке .\settings

Код скрипта

//@script_name AuthorComments
//@script_display_name  Авторские комментарии
//@script_description Вставляет в модуль комментарии об авторе добавления, изменения и удаления кода
//@script_author m.bolsun
//@script_developer_url https://turboconf.ru
//@script_hotkey Alt+A ВставитьДобавление
//@script_hotkey Alt+D ВставитьУдаление
//@script_hotkey Alt+C ВставитьИзменение
//@retain_clipboard 1
//@enterprise_mode 0
//@hide_actions 1
//@script_version 2

Перем Настройки;

Процедура ВставитьДобавление()
	ВставитьКомментарий("добавление")
КонецПроцедуры

Процедура ВставитьИзменение()
	ВставитьКомментарий("изменение")	
КонецПроцедуры

Процедура ВставитьУдаление()
	ВставитьКомментарий("удаление")
КонецПроцедуры

Функция ЗакомментироватьТекст(Текст)
	РегВыражение = Новый РегулярноеВыражение("^");
	РегВыражение.Многострочный  = Истина;
	Возврат РегВыражение.Заменить(Текст,"// ");
КонецФункции

Процедура ВставитьКомментарий(ВидКомментария)
	
	ТК = Новый ТурбоКонф; 

	Поз = 0;
	ВыделенныйТекст = "";
	
	Текст = ТК.ПолучитьТекстМодуля(ВыделенныйТекст, Поз);

	Если ВидКомментария = "добавление" Тогда
		ТекстШаблона = Настройки.ШаблонДобавлено;
	ИначеЕсли ВидКомментария = "изменение" Тогда
		ТекстШаблона = Настройки.ШаблонИзменено;
	ИначеЕсли ВидКомментария = "удаление" Тогда
		ТекстШаблона = Настройки.ШаблонУдалено;
	КонецЕсли;

	ТекстШаблона = СтрЗаменить(ТекстШаблона, "%ИмяПользователя%", Настройки.ИмяПользователя);
	ТекстШаблона = СтрЗаменить(ТекстШаблона, "%CurrentUser%", ПеременныеСреды()["USERNAME"]);
	
	ТекстШаблона = СтрЗаменить(ТекстШаблона, "%Компания%", Настройки.Компания);
	ТекстШаблона = СтрЗаменить(ТекстШаблона, "%CurrentUserDomain%", ПеременныеСреды()["USERDNSDOMAIN"]);

	ТекДата = Формат(ТекущаяДата(), Настройки.ФорматДаты);
	ТекстШаблона = СтрЗаменить(ТекстШаблона, "%ТекДата%", ТекДата);

	ТекстШаблона = СтрЗаменить(ТекстШаблона, "%ВставляемыйТекст%", СокрП(ВыделенныйТекст));

	ТекстШаблона = СтрЗаменить(ТекстШаблона, "%ЗакомментированныйТекст%", ЗакомментироватьТекст(СокрП(ВыделенныйТекст)));	

	ПозКурсора = СтрНайти(ТекстШаблона, "%_SetCursorPos_%");

	ТекстШаблона = СтрЗаменить(ТекстШаблона, "%_SetCursorPos_%", "");

	ПозКурсораX = 0;
	ПозКурсораY = 0;

	ТекСтрока = ТК.ПолучитьПозициюПоИндексу(Текст, Поз, ПозКурсораX, ПозКурсораY);

	ТК.ВставитьТекст(ТекстШаблона);
	
	Если ПозКурсора > 0 Тогда
		НомКолонки = 0;
		НомСтроки = 0;
	
		ТК.ПолучитьПозициюПоИндексу(ТекстШаблона, ПозКурсора, НомКолонки, НомСтроки);

		ТК.ПерейтиВПозицию(1, ПозКурсораY+НомСтроки) 
	КонецЕсли;

КонецПроцедуры

ФайлНастроекПоУмолчанию = "settings/AuthorComments/DefaultSettings.os";
ФайлНастроекПользователя = "settings/AuthorComments/Settings.os";

Файл = Новый Файл(ФайлНастроекПользователя);

Если Файл.Существует() Тогда
	Настройки = ЗагрузитьСценарий(ФайлНастроекПользователя).Настройки;	
Иначе
	Настройки = ЗагрузитьСценарий(ФайлНастроекПоУмолчанию).Настройки;	
КонецЕсли;